User:AngelRio/Flax

Rationale

Growing flax is simple. It is one of the most basic building blocks of many construction projects. Farming it in quantities, however, present a risk to the wrist and carpal tunnel due to its repetitive nature. We plan to remedy that by using both left and right hands, and minimizing the stress on the mouse-holding hand.

In essence, this replaces the function of the hotkeys for growing flax as they are effectively useless. The in-game hotkeys for growing flax make your avatar move making flax growing a very slow process.

This was written to reduce risk of RSI. With that in mind, please feel free to modify the code, and submit changes back. Thank you.

Instructions

1. Load the AHK file.
2. Position the flax menu below the TimeLoc window as shown below.
   • 
3. Go to overhead cartographic view (press F8 twice).
   1. Zoom in the closest level.
   2. Zoom out in 10 increments.
   3. Press Alt-L to freeze the zoom level.
4. Start planting flax. Press the Insert key.
   • Do not move the mouse at any time.
5. Wait for the weeds to grow.
6. Mouse over a flax bed and press the Delete or PageDown key.
   • Repeat for each flax bed.
   • Do not move the mouse when until the bed has been watered, weeded or harvested.
   • Use the PageDown key when watering, weeding or harvesting from left to right, the Delete key when doing it from right to left.

Notes

• Tested using 1024 x 768 resolution. If you have a different resolution, you may have to edit some of the values.
• I work in a very "laggy" environment (network and computer specs), and you may be able to tweak the delays to more optimal settings for your own system.

Bonus

For those tired of using their index fingers for clicking, you can now use the back tick (`) key as a left click. Cheers!

About AutoHotKey

I prefer using AutoHotKey since you can map certain keyboard sequences or mouse control into a "hotkey" such as Ctrl-Alt-Something, unlike with AC Tool where you need to be fast on the Alt-Tab draw. In this simple flax-growing script, we use the Insert, Delete and PageDown buttons which are not used in the game.

Code for AutoHotKey

;==============================================================================
; Plant a row of flax
;==============================================================================
PlantFlax()
{
  Loop 5
  {
    ; Wait for the proper position
    Sleep, 400

    ; Put a flax seed on the ground
    Click, 503, 55

    ; Wait for the proper position
    Sleep, 410

    ; Put a flax seed on the ground
    Click, 503, 55
	}
}

;==============================================================================
; Water, Weed or Harvest a bed of flax
;==============================================================================
WaterWeedHarvest(MouseX, MouseY)
{
  ; Click on the Flax bed
  Click %MouseX% %MouseY%

  ; Approximate the location of the menu to click
  NewMouseX := MouseX + 50

  ; Wait for the menu to show up
  ; Change this to a better implementation that is lag-resistant
  Sleep, 70

  ; Click on the menu item to Water/Weed/Harvest
  Click %NewMouseX% %MouseY%

  ; Finished one bed
  Return
}


;==============================================================================
; Watering/Weeding/Harvesting from Left to Right
;==============================================================================
PgDn::

  ; Get location of the mouse pointer
  MouseGetPos, MouseX, MouseY

  WaterWeedHarvest(MouseX, MouseY)
  
  NewMouseX := MouseX + 40
  MouseMove, %NewMouseX%, %MouseY%

  ; Finished one bed
  Return


;==============================================================================
; Watering/Weeding/Harvesting from Right to Left
;==============================================================================
Delete::

  ; Get location of the mouse pointer
  MouseGetPos, MouseX, MouseY

  WaterWeedHarvest(MouseX, MouseY)

  ; Move the mouse near the next flax bed
  NewMouseX := MouseX - 40
  MouseMove, %NewMouseX%, %MouseY%

  ; Finished one bed
  Return

;==============================================================================
; Planting two rows of flax
;==============================================================================
Insert::

  ; Move to the right...
  Click, 1024, 384

  PlantFlax()

  ; Move down, a bit to the right...
  Click, 585, 477
  Sleep, 1385

  ; Move to the left...
  Click, 0, 384

  PlantFlax()

  ; Move to the center ready for weeding
  Click, 692, 356

  ; End of Flax Planting
  Return

;==============================================================================
; Mouse click on ` key
;==============================================================================
`::
  Click
  Return

Tab::
  ; Get location of the mouse pointer
  MouseGetPos, MouseX, MouseY
  NewMouseY := MouseY
  
  WaterWeedHarvest(MouseX, NewMouseY)

  ; Move the mouse near the next flax bed
  NewMouseX := MouseX
  MouseMove, %NewMouseX%, %MouseY%

  ; Finished one bed
  Return

;==============================================================================
; Expand abbreviations
;==============================================================================